SQL 2005 try catch 的详细介绍

BEGIN TRY            -- TRY 模块
       -- 业务处理
END TRY
BEGIN CATCH          -- CATCH 模块
       -- 错误处理
END CATCH

BEGIN TRY
       -- 业务处理
       RAISERROR('start', 10, 1)     -- 此句不会导致处理转到CATCH 模块
       RAISERROR('warning', 11, 1)   -- 此句会导致处理转到CATCH 模块
       RAISERROR('finish', 10, 1)    -- 由于上一句导致处理转到CATCH 模块, 故此句不会被执行
END TRY
BEGIN CATCH
       -- 错误处理
       SELECT
              ERROR_MESSAGE()  -- 返回warning
END CATCH

CREATE PROC procedure_name
AS
SET NOCOUNT ON
 
-- 当前的事务数
DECLARE
       @trancount int
SELECT
       @trancount = @@TRANCOUNT
 
-- TRY...CATCH 处理
BEGIN TRY
       -- ========================================
       -- 标准的事务处理模块块
       -- a. 开启事务, 或者设置事务保存点
       IF @trancount = 0
              BEGIN TRAN
       ELSE
              SAVE TRAN TRAN_SavePoint
 
       -- b. 这里放置处于事务中的各种处理语句
 
       -- c. 提交事务
       --    有可提交的事务, 并且事务是在当前模块中开启的情况下, 才提交事务
       IF XACT_STATE() = 1 AND @trancount = 0
              COMMIT
       -- ========================================
 
      
 
       -- ========================================
       -- 为了防止TRY 中有遗漏的事务处理, 可以在TRY 模拟的结束部分做最终的判断
       IF @trancount = 0
       BEGIN
              IF XACT_STATE() = -1
                     ROLLBACK TRAN
              ELSE
              BEGIN        
                     WHILE @@TRANCOUNT > 0
                           COMMIT TRAN
              END
       END
END TRY
BEGIN CATCH
       -- ========================================
       -- 在CATCH 模块, 应该首先处理事务
       IF XACT_STATE() <> 0
       BEGIN
              IF @trancount = 0
                     ROLLBACK TRAN
 -- XACT_STATE 为-1 时, 不能回滚到事务保存点, 这种情况留给外层调用者做统一的事务回滚
-- 通过@@TRANCOUNT > @trancount 的判断, 即使在TRY 模块中没有设置事务保存点的情况下跳到此步骤, 也不会出错
              ELSE IF XACT_STATE() = 1 AND @@TRANCOUNT > @trancount
                     ROLLBACK TRAN TRAN_SavePoint
       END
 
       -- ========================================
       -- 错误消息处理
       -- a. 获取错误信息
       -- 这提提取了错误相关的全部信息, 可以根据实际需要调整
       DECLARE
              @error_number int,
              @error_message nvarchar(2048),
              @error_severity int,
              @error_state int,
              @error_line int,
              @error_procedure nvarchar(126),
              @user_name nvarchar(128),
              @host_name nvarchar(128)
 
       SELECT
              @error_number = ERROR_NUMBER(),
              @error_message = ERROR_MESSAGE(),
              @error_severity = ERROR_SEVERITY(),
              @error_state = ERROR_STATE(),
              @error_line = ERROR_LINE(),
              @error_procedure = ERROR_PROCEDURE(),
              @user_name = SUSER_SNAME(),
              @host_name = HOST_NAME()
 
       -- b. 对于重要的业务处理存储过程, 应该考虑把错误记录到表中备查(这个表需要先建立)
       --    记录错误应该在没有事务的情况下进行了, 否则可能因为外层事务的影响导致保存失败
       IF XACT_STATE() = 0  
              INSERT dbo.tb_ErrorLog(
                     error_number,
                     error_message,
                     error_severity,
                     error_state,
                     error_line,
                     error_procedure,
                     user_name,
                     host_name,
                     indate)
              VALUES(
                     @error_number,
                     @error_message,
                     @error_severity,
                     @error_state,
                     @error_line,
                     @error_procedure,
                     @user_name,
                     @host_name,
                     GETDATE())
 
 -- c. 如果没有打算在CATCH 模块中对错误进行处理, 则应该抛出错误给调用者
 -- 注: 不允许在被SSB 调用的存储过程中, 将错误或者其他信息抛出
 -- 因为SSB 是自动工作的, 如果它调用的存储过程有抛出信息, 则这个信息会被直接记录到SQL Server 系统日志
  -- 而目前SSB 的消息数量是很多的, 这会导致SQL Server 日志爆涨掉
 -- 对于被SSB 调用的存储过程, 应该在CATCH 模块中加入自己的错误处理(最简单的就是将错误记录到表中)
       RAISERROR(
       N'User: %s, Host: %s, Procedure: %s, Error %d, Level %d, State %d, Line %d, Message: %s ',
              @error_severity,
              1,
              @user_name,
              @host_name,
              @error_procedure,
              @error_number,
              @error_severity,
              @error_state,
              @error_line,
              @error_message)
END CATCH
GO

DECLARE
   @sp_re int
 
EXEC @sp_re = dbo.procedure_name
 
IF @sp_re <> 0
   RAISERROR('has some error', 16, 1)